Задача 1. Найти площадь ограниченную параболой x=2y^2 и линией x=y+3.
Решение 1.
Нарисуем эту область
> restart:
> x1:=2*y^2: x2:=y+3:
> plot({[x1,y,y=-2..2],[x2,y,y=-2..2]});
Найдем точки пересечения кривых (пределы интегрирования)
> solve({x=2*y^2,x=y+3});
> s:=Int(Int(1,x=2*y^2..y+3),y=-1..3/2);
> value(s);
Задача 2.Найти среднее значение функции f=y ch (x) над областью, ограниченной кривыми x=0 , y=2 , y=sqrt(x).
Решение 2.
Посмотрим на эту область
> restart:
> plot({[0,t,t=-1..2.5],
>[t,2,t= 0..5],
>[t,sqrt(t),t=0..5]},thickness=2);
Область описывается, как 0<y<2, 0<x<y^2. Вычислим среднее
> s:=Int(Int(y*cosh(x),x=0..y^2),y=0..2)/
>Int(Int(1,x=0..y^2),y=0..2);
> value(s); evalf(");
Задача 3.Найти объем тела ограниченного поверхностями f=x^2+2y^2 - сверху, и g=6-2x^2-y^2 - снизу, над кругом единичного радиуса x^2+y^2 <1
Решение 3.
Нам необходимо найти объем следующей фигуры
> restart: with(plots):
> f:=x^2+2*y^2: g:=6-2*x^2-y^2:
Нарисуем поверхности
> surf:=plot3d({f, g },x=-1.2..1.2,y=-1.2..1.2):
и цилиндр единичного радиуса
> cyl:=plot3d([cos(t),sin(t),z],t=0..2*Pi,z=0..6):
Выведем их на экран
> display3d({surf,cyl});
Чтобы найти объем данной фигуры необходимо вычислить интеграл
> Int(Int(g-f,y=-sqrt(1-x^2)..sqrt(1-x^2)),x=-1..1);
> value(");
Задача 4. Используя сферические координаты найти объем тела, ограниченного сферой с x^2+y^2+z^2=4вырезанным в ней цилиндром x^2+y^2=1.
Решение 4.
В сферических координатах сфера задается как r=2, цилиндр как r sin(f)=1 . Нам надо выразить декартовы координаты x,y,z через сферические, подставив данные значения r для сферы и для цилиндра
> restart: with(plots):
> rs:=2; rc:=1/sin(phi);
> x:=sin(phi)*cos(theta);
> y:=sin(phi)*sin(theta);
> z:=cos(phi);
Зададим точку на сфере и цилиндре
> sf:=[rs*x,rs*y,rs*z]:
> cyl:=[rc*x,rc*y,2*phi-Pi]:
Нарисуем сферу и цилиндр
> plot3d({sf,cyl},theta=0..2*Pi,phi=0..Pi);
Вычислим пределы интегрирования, решив систему уравнений
> _EnvAllSolutions := true:
> solve({r=2,r*sin(phi)=1});
здесь B1 и Z1 целые числа. Таким образом, наша фигура может быть получена вращением следующего сегмента вокруг оси Z
> plot({[rs*sin(v),rs*cos(v),v=Pi/6..5*Pi/6],
> [1,v,v=-sqrt(3)..sqrt(3)]},-3..3,-2..2);
Вычислим ее объем
> Int(Int(Int((rho^2)*sin(phi),
> rho=1/sin(phi)..2),phi=Pi/6..5*Pi/6), theta=0..2*Pi);
> value(");
Задача 5.Используя цилиндрические координаты найти объем тела, ограниченного поверхностью (x^2+y^2)^5/2=(x^2-y^2)^2и плоскостями z=0, z=2.
Решение 5.
В цилиндрических координатах поверхность параметризуется как
r = ( cos^2 ( q ) -- sin^2 (q) ) ^ 2. Зададим параметрически ее
> restart:
> xs:=cos(2*theta)^2*cos(theta):
> ys:=cos(2*theta)^2*sin(theta):
> surf:=plot3d([xs,ys,z],theta=0..2*Pi,z=-1..3,grid=[60,5]):
и две плоскости
> planes:=plot3d({0,2},x=-1.5..1.5,y=-1.5..1.5):
Нарисуем их
> with(plots):
> display3d({surf,planes});
Посмотрим сечение
> polarplot((cos(theta)^2-sin(theta)^2)^2,theta=0..2*Pi);
Область интегрирования определить легко
0 < z < 2 , 0 < q < 2 p , 0 < r < ( cos^2 ( q ) -- sin^2 (q) ) ^ 2
Объем тела равен
> v:=Int(Int(Int(rho,rho=0..(cos(theta)^2-sin(theta)^2)^2),
> theta=0..2*Pi),z=0..2);
> value(v);
Как мы видим, главная проблема в определении пределов интегрирования. Существует несколько библиотек программ, которые позволяют находить эти пределы. Эти же пакеты предназначены для изучения векторных полей (можно посмотреть доказательство теорем Стокса, Грина и др.). Смотри www-сервер Maple Software.